TITLE:
  Ch 11a: Add Two-Way and Three-Way Interactions Among Level-3 Effects
  Predicting Student Closeness

DATA:
  ! Prior necessary data manipulation conducted using other programs
  FILE = MPLUS_Chapter11a.csv;
  FORMAT = FREE;

DEFINE:
  CMgCMe = CMg50*CMemo5;
  CMgCMv = CMg50*CMvic3;
  CMeCMv = CMemo5*CMvic3;
  CMgev  = CMg50*CMemo5*CMvic3;

VARIABLE:
  NAMES = ClassID grade size StudID girl SMclose SMvic CMclose CMvic CMg CMemo
          size23 grade35 CMg50 CMemo5 CMvic3 WCclose SMvic3 WCvic wave emo vic close
          time1 time2 w3 WSclose vic3 WSvic emo5 WCemo;
  USEVARIABLES = close time1 girl CMg50 CMemo5 WSvic WCvic CMvic3
                  CMgCMe CMgCMv CMeCMv CMgev;
  MISSING = ALL (-9999);
  CLUSTER = ClassID StudID;
  WITHIN = time1 WSvic;
  BETWEEN = (StudID) girl WCvic (ClassID) CMg50 CMemo5 CMvic3 CMgCMe CMgCMv CMeCMv CMgev;

ANALYSIS:
  ESTIMATOR = ML;
  PROCESSORS = 4;
  TYPE = THREELEVEL RANDOM;

MODEL:

%WITHIN%
  close;
  lin | close ON time1;
  intL1v | close ON WSvic;

%BETWEEN StudID%
  close lin intL1v;
  close lin intL1v WITH close lin intL1v;
  close lin ON girl (bintL2g blinL2g);
  intL2v | close ON WCvic;

%BETWEEN ClassID%
  [close lin intL1v intL2v] (int btime1 bintL1v bintL2v);
  close lin intL1v@0 intL2v@0;
  close WITH lin;
  close lin ON CMg50  (bintL3g blinL3g);
  close lin ON CMemo5 (bintL3e blinL3e);
  close     ON CMvic3 (bintL3v);
  close lin ON CMgCMe (biL3ge blL3ge);
  close lin ON CMgCMv (biL3gv blL3gv);
  close lin ON CMeCMv (biL3ev blL3ev);
  close lin ON CMgev (biL3gev blL3gev);