TITLE:
  Ch 8: Checking Inter-Variable Interactions via PMC Negative Mood by PMC Stressors

DATA:
  ! Prior necessary data manipulation conducted using other programs
  FILE = MPLUS_Chapter8.csv;
  FORMAT = FREE;

DEFINE:
  sexage = women*age80;
  sexPMs = women*PMstr40;
  PMmPMs = PMmood2*PMstr40;
  WPmWPs = WPmood*WPstr;

VARIABLE:
  NAMES = PersonID women baseage session studyday dayweek weekend symp mood stress
          PMmood PMstr age80 mood2 WPmood PMmood2 WPstr PMstr40;
  USEVARIABLES = symp women age80 PMmood2 WPmood WPstr PMstr40 sexage sexPMs
                  PMmPMs WPmWPs;
  MISSING = ALL (-9999);
  CLUSTER = PersonID;
  WITHIN = WPmood WPstr WPmWPs;
  BETWEEN = women age80 PMmood2 PMstr40 sexage sexPMs PMmPMs;

ANALYSIS:
  ESTIMATOR = ML;
  PROCESSORS = 4;
  TYPE = TWOLEVEL RANDOM;

MODEL:

%WITHIN%
  symp;
  L1mood | symp ON WPmood;
  L1str | symp ON WPstr;
  L1mL1s | symp ON WPmWPs;

%BETWEEN%
  [symp L1mood L1str L1mL1s] (int bWPmood bWPstr bWPmWPs);
  symp L1mood@0 L1str@0 L1mL1s@0;
  symp ON women age80 sexage (bwomen bage80 bsexage);
  symp ON PMmood2 PMstr40 (bPMmood2 bPMstr40);
  symp ON sexPMs PMmPMs (bsexPMs bPMmPMs);
  L1mood ON PMstr40 (bL1mPMs);
  L1str ON women PMmood2 (bsexL1s bPMmL1s);

MODEL CONSTRAINT:
  NEW(est1-est9);
! est1: BP Negative Mood by BP Stressors
  est1 = bPMmPMs*1;
! est2: BP Negative Mood by Contextual Stressors
  est2 = bPMmPMs*1 - bPMmL1s*1;
! est3: BP Negative Mood by WP Stressors
  est3 = bPMmL1s*1;
! est4: Contextual Negative Mood by BP Stressors
  est4 = bPMmPMs*1 - bL1mPMs*1;
! est5: Contextual Negative Mood by Contextual Stressors
  est5 = bPMmPMs*1 - bL1mPMs*1 - bPMmL1s*1 + bWPmWPs*1;
! est6: Contextual Negative Mood by WP Stressors
  est6 = bPMmL1s*1 - bWPmWPs*1;
! est7: WP Negative Mood by BP Stressors
  est7 = bL1mPMs*1;
! est8: WP Negative Mood by Contextual Stressors
  est8 = bL1mPMs*1 - bWPmWPs*1;
! est9: WP Negative Mood by WP Stressors
  est9 = bWPmWPs*1;